;hsqc_fb.ref, avance500 07/15/02

#include "Gradaph.incl"
#include "Avance.incl"

;1 hn, 15n edited noesy to water protons
;history
;written by sg 2/23/93
;put in water flip_back 6/1/93
;change to waternh 7/29/93
;change to hnhsqc.dif 6/27/95
;change to hsqcg.dat 10/7/95
;changed to hsqc_fb.yt  for DMX500 6/3/96
;copied from hsqc_fb.dat_r
;Updated and checked 2/7/97 mam
;uthsasa avance500, 7/15/02, aph

;Adjust these as appropriate by commenting in/out
#define FLIP_BACK
#define CARBON_LABEL
#define WATER_GATE

;Proton settings - Set carrier to H2O (ca 4.7 ppm)
;p1    -  square 90 1H @ pl1, for excitation, typically p1 = 8.9u @ pl1 = -2dB
;p2    -  square 90 1H @ pl1, for watergate, typically p2 = 1000u @ pl2 = +39.0dB
;p3    -  shaped 90 1H @ sp0, for water flipback, typically p3 = 2m @ sp0 = +38.5
;         "spnam0 seduce1.jc", "spoffs0 0"

;Nitrogen settings - Set carrier to amide center (ca. 118 ppm)
;p7     -  square 90 15N @ pl7, for excitation, typically p7 = 45u @ pl1 = -3.1dB
;pcpd3  -  square 90 15N @ pl3, for cpd, typically pcpd3 = 200u @ pl3 = +10.0

;The following is only necessary if CARBON_LABEL is defined
;13C pulses - carrier is set according to fqlist1 frequency list
;             chose/edit in ased, should have two values,
;             first is CA (56 ppm), second is CO (176 ppm)
;p5     -  square 90 13C @ pl5, for excitation, p5 must equal 28.7u, typically pl5 = +2.6

;in0=1/(2sw)    nitrogen spectral window
;L3             nitrogen t1 points

;Gradient settings
;Note1 - grad times are preset, you do not need to adjust these
;Note2 - set grad params according to table below, note integer in first
;column is substituted to yield the parameter that is to be adjusted
;example for grad# 0, set "gpnam0 sine.32", "gpx0 20", "gpy0 0", "gpz0 -40"
;
;grad#  gpnam#          gpx#    gpy#    gpz#
;0      sine.32         20      0       -40 
;1      sine.32         20      0        40     

;Other Adjustments
;d1  -   recycle time, typically d1 = 1s

;Optional Adjustments 
;phcor14  -  phase adjustment for p2@pl2 vs p1@pl1, typically +/- 1 degree
;phcor18  -  phase adjustment for p2@pl2 vs p1@pl1, typically +/- 1 degree
;phcor13  -  phase adjustment for p3@sp0 vs p1@pl1, typically +/- 1 degree

;PRESET DELAYS - DO NOT ADJUST ANYTHING BELOW THIS POINT
;
"p15=2.5m"
"p16=2.0m"
"p17=0.4m"
;
#ifdef CARBON_LABEL
"d0=in0*0.5 - p7*0.637 -4u -p5*2.0"
#else
"d0=in0*0.5 - p7*0.637 - 2*p1"	
#endif
;
"d4=2.5m"			;1/4Jhn - use 2.25m for larger proteins
"d11=5m"
"d12=1m"
"d26=p7-p1"
"d27=p5-p1"
define delay pd2
"pd2=p2"
define delay pd3
"pd3=p3"

#define ON
#undef OFF

1	ze
2	d11 BLKGRAD
        1m
        d12
3 	d12*3.0
4	d11 do:f3
	10u pl1:f1
        10u pl7:f3
	10u pl5:f2
#ifdef ON
#ifdef CARBON_LABEL
	10u pl5:f2
	10u fq1:f2	;jump to 56ppm
#endif
;*****	presaturation	*****
	d1
	1m UNBLKGRAD
;*****	INEPT from proton to nitrogen antiphase *****
	(p1 ph0):f1
	d4
	(p7*2 ph6):f3 (d26 p1*2 ph4):f1
	d4
	(p1 ph6):f1
	6u pl2:f1
#ifdef FLIP_BACK
	(p2 ph18:r):f1
	2u
#else
	pd2
	2u
#endif
	p15:gp0
	1.5m pl1:f1
;*****	nitrogen evolution period *****
	(p7 ph3):f3
	d0
#ifdef CARBON_LABEL
	2u
	(p5*2 ph10):f2 (d27 p1*2 ph0):f1
	2u fq1:f2 	;jump to 177ppm
	4u
	(p5*2 ph10):f2
#else
	(p1*2 ph0):f1 	;proton refocusing
#endif
	d0
	(p7 ph7):f3
	2u
	p16:gp0
	1m
#ifdef FLIP_BACK
	10u 
	(p3:sp0 ph13:r):f1
#else
	5u
	pd3
#endif
	10u
	12u pl1:f1
	(p1 ph0):f1
#ifdef WATER_GATE
	p17:gp1
	950u pl2:f1
	(p2 ph14:r):f1
	2u pl1:f1
	5u 
	(p1*2 ph15):f1
	2u pl2:f1
	5u
	(p7*2 ph10):f3 (p2 ph14:r):f1
	2u
	p17:gp1
#else
	400u pl1:f1
	950u
	pd2
	(p7*2 ph10):f3 (d26 p1*2 ph15)
	pd2
	400u
#endif
	(2u ph0)
	948u pl3:f3  	;996u for better ph1 for DMX500
        5u
#endif
	go=2 ph31 cpds3:f3
	1m BLKGRAD
	d11 do:f2 do:f3 wr #0 if #0 zd
d12 ip3                 ;States-TPPI in nitrogen
lo to 3 times 2
d12 id0
d12 ip31
d12 ip31
lo to 4 times l3        ;loop over nitrogen t1 points
d12 do:f2
d12 do:f3
exit

ph0=0
ph1=0
ph3=0 2 0 2 2 0 2 0
ph4=1
ph6=1
ph7=0
ph10=0
ph13=2			;adjust using phcor13
ph14=2 2 0 0		;adjust using phcor14 
ph15=0 0 2 2
ph18=0			;adjust using phcor18
ph31=0 2 0 2 2 0 2 0